スクリプトをもっと詳しく

選択ファイルをFTPで転送/二つのフォルダを比較

//選択したファイルをWinSCPで送信するスクリプトサンプル
//ディレクトリが指定された場合、再帰的に下位階層も処理されるようです。
//もちろん、コマンドラインオプションを変更することでSFTP/FTPS/FTP/SCP・・・といったWinSCPが対応しているプロトコルに対応させることができます
//なお、平文でスクリプトは記述されなければならないので、FTPアカウントの管理は慎重に行ってください
//WinSCPのファイル名はUTF8として転送されますので、FTPクライアントの文字コードの設定などを確認してください

//簡単な文法チェックを行う
CheckGrammar = 1

//バーにスクリプトを置いた時のアイコン画像を明示的に指定、iconは静的なコマンドなので変数展開できない
icon = D:\TOOLS\FileTool\WinSCP\WinSCP.exe

//WinSCPのフルパス（コマンド版を使用）
var $WinSCPPath$ = D:\TOOLS\FileTool\WinSCP\WinSCP.com

//FTPユーザーID
var $UserID$ = hoge

//FTPパスワード
var $PassWord$ = hogehoge

//ホスト名
var $HostName$ = 192.168.10.50

//ファイルをアップロードするディレクトリ、inputなどを使用して手入力可にしたり、外部から渡すようにしても良いでしょう
var $TargetDir$ = /home/hoge/test

//ループの中で変数を定義すると、繰り返し時に再定義エラーになるのでループの外で定義
var $TargetUrl$ = ftp://$UserID$:$PassWord$@$HostName$
var $Command$
var $Result$
For
	$Command$ = $WinSCPPath$ /command "option batch on" "option confirm off" "option transfer binary" "open $TargetUrl$ -passive" "cd $TargetDir$" "put ""?selfile?""" "exit"
	$Result$ = Call,$Command$

	if $Result$ != 0
		MessageBoxOK=エラーコード($Result$)が返りました $Command$
		break
	endif
Next

//現在、画面分割して開いている二つのディレクトリをWinMergeを用いて比較するスクリプト

CheckGrammar=1

//アイコン画像を明示的に指定、iconは静的なコマンドなので変数展開できない
icon = %ProgramFiles%\WinMerge\WinMergeU.exe

//WinMergeのインストールパス
var $WinMergePath$=%ProgramFiles%\WinMerge\WinMergeU.exe

OpenMode=0
MultiCommandMode=0
ShiftSilentMode=0
BootDir=
BootMode=0
SendInfoMode=0

//画面分割していない場合は１個だけ渡す
if ?State:DivisionWindow? == 0
	CommandLineOption=?NowDir?
	Shell=$WinMergePath$
	exit
endif

//画面分割している場合はパスを２個渡す
CommandlineOption="?TargetDir?" ?NowDir?
Shell=$WinMergePath$
EOF

//環境変数「%ProgramFiles%」はx64環境でx86版なら「C:\Program Files (x86)」
//x86環境か、x64環境でx64版なら「C:\Program Files」と展開されることにご注意ください